今回のテーマ

前回は，Perlのattributeという仕組みを解説しました。今回は，さらにattributeの実戦的な利用方法として，(Perlとしては実験的な実装という扱いですが)パッケージ固有のattribute実装の方法と，Class::Component::Attributeを拡張してplugin作りを便利にする方法を取り上げます。

サンプルアプリケーション

本連載では，プラガブルなモジュールを作製するという事を考えて，Gopperという実際に実行可能なサンプルアプリケーションを元に解説を行ないます。GopperはCodeRepos上のsvnリポジトリに置いてあるので各自checkoutしてください。

svn co -r 659 http://svn.coderepos.org/share/lang/perl/Gopper/trunk Gopper

パッケージ固有のattribute実装

Perlのattributeに関しては前回の記事を参照してください。今回はPerlのattributeで利用できるMODIFY_CODE_ATTRIBUTESについてを深く掘り下げて解説します。

attributeを独自に定義する為に

attributeを独自に定義するには，MODIFY_type_ATTRIBUTES メソッドを定義する必要が有ります。typeには， CODE / SCALAR / ARRAY / HASH の4種類のどれかで置きかえます。CODEだったらMODIFY_CODE_ATTRIBUTESになります。

attributeは，BEGINフェーズにて解釈されるので，MODIFY_type_ATTRIBUTESメソッドの定義はattributeを利用するコードよりも先に書かれている必要があります。

# test.pl
use strict;
use warnings;

BEGIN { print "B:1\n" }

sub MODIFY_CODE_ATTRIBUTES {
    print "MODIFY_CODE_ATTRIBUTES\n";
    return;
}

BEGIN { print "B:2\n" }

sub test: hoge {}

BEGIN { print "B:3\n" }

$ perl ./test.pl
B:1
B:2
MODIFY_CODE_ATTRIBUTES
B:3

# test2.pl
use strict;
use warnings;

BEGIN { print "B:1\n" }

sub test: hoge {} # あれ？MODIFY_CODE_ATTRIBUTESは？

BEGIN { print "B:2\n" }

sub MODIFY_CODE_ATTRIBUTES {
    print "MODIFY_CODE_ATTRIBUTES\n";
    return;
}

BEGIN { print "B:3\n" }

$ perl ./test2.pl
B:1
Invalid CODE attribute: hoge at ./test2.pl line 6
BEGIN failed--compilation aborted at ./test2.pl line 6.

SCALAR / ARRAY / HASH に関しては，それぞれ変数をmy宣言する時に利用されるattributeをハンドリングします。

# test3.pl
use strict;
use warnings;

sub MODIFY_SCALAR_ATTRIBUTES {
    print "MODIFY_SCALAR_ATTRIBUTES\n";
    return;
}

sub MODIFY_ARRAY_ATTRIBUTES {
    print "MODIFY_ARRAY_ATTRIBUTES\n";
    return;
}

sub MODIFY_HASH_ATTRIBUTES {
    print "MODIFY_HASH_ATTRIBUTES\n";
    return;
}

my $scalar : hoge ;
my @array : hoge ;
my %hash : hoge ;

$ perl ./test3.pl
MODIFY_SCALAR_ATTRIBUTES
MODIFY_ARRAY_ATTRIBUTES
MODIFY_HASH_ATTRIBUTES

MODIFY_type_ATTRIBUTESの実装内容

MODIFY_type_ATTRIBUTESが呼び出される仕組みはattributes.pmに記述されており。perldoc -m attributesで確認することが出来ます。Perlのコンパイラはsub method : attributes {}のような記述があると内部的にattributesをロードし，attributes->importを呼び出します。importを呼び出すときにattributeされるオブジェクトのリファレンスとattribute宣言の内容のリストを引数として渡します。

例えば下記のコードのような挙動になります。

sub hoge : attr1 attr2 attr3 {}
# 上のような宣言が有るときは，内部的に下記を実行
require attributes;
attributes->import( \&hoge, qw( attr1 attr2 attr3 ) );

この時のimportで渡される一つ目の引数のリファレンスの内容を見て，どのMODIFY_type_ATTRIBUTESを使うかを決定しています。