モバイルファクトリーの伏原です。 私は今回Test::Baseというモジュールを紹介させてもらいます。

Test::Baseとは

Test::Baseは，Kwikiなどの作者として知られるIngy döt Net氏が作成した“Data Driven Testing Framework（データ駆動型テストフレームワーク）”です。 データ駆動型テストとは何なのか，実際のテストを見て頂くのが一番早いと思うので，早速実際にTest::Baseを使ったテストを書いてみることにします。

今回使うサンプルプログラム

NabeAtzz問題を解くプログラムを作ります。NabeAtzz問題にはいくつかのバリエーションがありますが，今回は以下の条件を満たすもの，と言うことにします。

• 1からnまでの整数に対して
• 3の倍数の時は“fool”と出力する
• 5の倍数の時は“dog”と出力する
• いずれかの桁に3が含まれる整数の時も“fool”と出力する
• それ以外の数の場合は整数を“[1]”のように[]で囲って出力する

これを満たすために，とりあえず以下のプログラムを作ってみました。

#!/usr/bin/perl -Ilib
use strict;
use warnings;

use NabeAtzz;

for my $n (1..$ARGV[0]) {
    print NabeAtzz->shout($n) . "\n";
}

ファイル作成後，

./nabeatzz.pl 20

のように実行すると，1から20までをNabeAtzz問題のルールに則って出力します。このプログラムを見ると，NabeAtzzモジュールのshoutメソッドが正しく動作すれば，プログラム全体が上手く動くことがわかります。ですので，実際にプログラム全体を動かさなくても，NabeAtzzモジュールのshoutメソッドをテストすれば良いことになります。

Test::Baseを使ったテストの書き方

さて，Test::Baseを使ってテストを書いていくわけですが，Test::BaseはTest::Moreで使えるメソッドと同じものをexportしているので，Test::Moreとまったく同じ書き方でテストを書くこともできます。まずは一番簡単な「3と5に関係しない数の時はそのまま数が返る」ことをテストします。

use strict;
use warnings;
use Test::Base;

use NabeAtzz;

plan tests => 3;

is(NabeAtzz->shout(1),  '[1]' );
is(NabeAtzz->shout(4),  '[4]' );
is(NabeAtzz->shout(19), '[19]');

まだNabeAtzz.pmを作っていないので，このテストを実行するともちろんエラーになります。まずは，このテストを通るプログラムを書いてみます。

package NabeAtzz;
use strict;
use warnings;

sub shout {
    my ($class, $number) = @_;

    return "[$number]";
}


1;

改めて以下のようにテストを実行すると，テストが正常に実行されると思います。

> perl -Ilib t/nabeatzz.1.t
1..3
ok 1
ok 2
ok 3

Test::Baseを使ったテストのスタイル

nabeatzz.1.tをよく見てみると，実は同じようなテストを繰り返していることがわかります。基本的にテストでよくあるパターンは，「関数への一定の入力値に対する出力値を期待した値と比較する」というもので，正常値・異常値・境界値などをチェックするために，入力値と期待値のセットが膨大になり，同じようなテストコードを書くことになります。 必然，コードをコピーアンドペーストなどで複製して修正するような書き方になり，ミスなどで誤ったテストスクリプトを書いてしまう原因になります。 Test::Baseでは，こういったパターンのテストをやりやすくするためのフレームワークです。先ほどのnabeatzz.1.tは，Test::Baseを使った本来のスタイルで書くと以下のように書くことができます。

use strict;
use warnings;
use Test::Base;

use NabeAtzz;

plan tests => 1*blocks;

filters {
    input    => [qw/chomp/],
    expected => [qw/chomp/],
};

run {
    my $block = shift;

    is(NabeAtzz->shout($block->input), $block->expected);
};

__END__

=== test 1
--- input
1
--- expected
[1]

=== test 4
--- input
4
--- expected
[4]

=== test 19
--- input
19
--- expected
[19]

スクリプトの行数自体は長くなってしまいましたが，見てのとおり，テストを行うロジックとテストに対して渡す入力値・期待値が完全に分離されています。これであれば単なるテストケースの追加でテストのロジックを壊してしまう心配がなくなります。 では色々と登場した新しい記述について順番に説明していこうと思います。