多重継承しないほうがよい場合
前回は多重継承を利用してクラスを拡張するときにありがちな問題と，そのひとつの解決策を見てきましたが，クラスにいくつかのメソッドを追加したいだけであれば，むしろ継承を利用しないほうがふさわしい場合もあります。
たとえば「コウモリ」というクラスを実装するとき，「乳を出す」というメソッドのために「ほ乳類」というクラスを，「空を飛ぶ」というメソッドのために「鳥類」というクラスを継承するのは――たしかにそれで当座の問題は解決するかもしれませんが――違和感が残ります。
use strict;
use warnings;
use Test::More tests => 4;
package Mammal;
sub new { bless {}, shift; }
sub produce_milk { print "I can produce milk.\n"; }
package Bird;
sub new { bless {}, shift; }
sub fly { print "I can fly.\n"; }
package Bat;
use base qw(Mammal Bird);
package main;
my $bat = Bat->new;
can_ok($bat => 'produce_milk'); # ok
can_ok($bat => 'fly'); # ok
ok($bat->isa('Mammal')); # ok
ok($bat->isa('Bird')); # ok でも，コウモリは本当に鳥類ですか!?
このような多重継承によるメソッド拡張の問題をPerlの世界ではどう解消してきたのか。今回は，その問題を追いかけていきましょう。
Exporterを使った解決策とその問題点
さて，上の例の場合，コウモリはほ乳類ですから，BatクラスとMammalクラスは純粋に「is a」の関係にあります。だから，問題となるのは，Batクラスに（Birdクラスと共通の）flyメソッドを追加する部分だけです。
Perl 5の場合，メソッドとサブルーチンに実質的な差はありません。よそで定義されたサブルーチンを取り込む方法としては，コアに入っているExporterモジュールとimportメソッドを使うのが古典的な手法でした。
use strict;
use warnings;
use Test::More tests => 4;
package Mammal;
sub new { bless {}, shift; }
sub produce_milk { print "I can produce milk.\n"; }
package Bird;
use base 'Exporter';
our @EXPORT_OK = qw(fly);
sub new { bless {}, shift; }
sub fly { print "I can fly.\n"; }
package Bat;
Bird->import('fly'); # use Bird 'fly';
use base 'Mammal';
package main;
my $bat = Bat->new;
can_ok($bat => 'produce_milk'); # ok
can_ok($bat => 'fly'); # ok
ok($bat->isa('Mammal')); # ok
ok(!$bat->isa('Bird')); # ok コウモリは鳥類ではなくなりました
そもそも鳥類の「飛ぶ能力」はほ乳類に貸し出せるようなものなのか？ とか，コウモリは鳥類を使役（use）するから飛べるというのは論理的におかしくないか？ という根本的な疑問を別にすれば，これでひとまずうまくいくように見えます。
でも，Birdクラスが，たとえばこうなっていたら，どうでしょう。
package Bird;
use base 'Exporter';
our @EXPORT_OK = qw(fly);
sub new { bless {}, shift; }
sub fly_with { 'wings'; }
sub fly {
my $self = shift;
print "I can fly with ".$self->fly_with.".\n";
}
こう変えても，先ほどのテストの範囲内ではうまく飛べるように見えます。でも，実際にコウモリを飛ばそうとすると，「Can't locate object method "fly_with" via package "Bat" 」という実行時エラーが発生します（BatはMammalしか継承していませんので，当然Birdクラスのfly_withメソッドは引き継がれません）。
このような欠点があることから，前回も登場したダミアン・コンウェイ氏が，Perl 6の設計が始まった2000年に刊行した著書『オブジェクト指向Perlマスターコース』の中では，Exporterを利用する手法はばっさりと切り捨てられていました。
Exporterモジュールとimportサブルーチンは通常のPerlにおいては重要であるが、オブジェクト指向Perlではほとんど使用されない。これは、クラスから変数またはサブルーチンをエクスポートすることがオブジェクト指向のカプセル化原理に反するためである。
山根ドキュメンテーション訳p.76
