モダンPerlの世界へようこそ

第21回　KiokuDB：マッピングが複雑すぎると感じたら

2009年11月30日

石垣憲一

Perl, モダンPerl, KiokuDB

データベース, スコープ, テキスト, オブジェクト, Perl

Shibuya.pm #12連動企画

本日開催のShibuya Perl Mongersテクニカルトーク#12のテーマは "No Perl, NoSQL, NoKVS" または "Not only Perl, Not only SQL, Not only KVS" ということなので，今回はそれにあわせてYAPC::Asia 2009でも紹介されていたKiokuDBについて簡単に取り上げてみます。

オブジェクトをまるごと保存する

牧大輔氏も『モダンPerl入門』のなかで，データベースをハッシュテーブルのようにとらえて，「基本的にプライマリキーからデータを持ってくる構成のみにすると，ORMを使用することによりキャッシュの導入も含めてチューニングが楽になります」と書いているように，Perlの世界では最近RDBMSやその上位層で頑張りすぎるより，モデリングの仕方そのものを工夫して実装や保守のしやすさを向上させたりスケーラビリティの確保を目指す現場も増えてきているようです。リレーショナルデータベースのデータをオブジェクトにマッピングするのではなく，関係性まで含んだオブジェクトをまるごと保存したり取り出したりできるようにするKiokuDBもその流れの一環にあるものと見てよいでしょう。

オブジェクトをまるごと保存といってもピンとこないかもしれませんので，まずはテキストも写真も投稿できる掲示板のようなものをつくることを考えてみます。テキストにも写真にも対応したクラスをつくってもよいのですが，今回は写真とテキストについてはクラスをわけてみましょう。

テキストを持たせるクラスは簡単です。

package Post;

use Moose;

has 'name'   => (is => 'rw', isa => 'Str');
has 'body'   => (is => 'rw', isa => 'Str');
has 'author' => (is => 'rw', isa => 'Person', weak_ref => 1);

__PACKAGE__->meta->make_immutable;

写真を持たせるクラスも，Perlレベルでは大差ありません。が，O/Rマッパを使う場合は当然テキストとは異なる型を持たせることになるでしょうから，ここではクラスをわけてあります。

package Photo;

use Moose;

has 'name'   => (is => 'rw', isa => 'Str');
has 'image'  => (is => 'rw');
has 'author' => (is => 'rw', isa => 'Person', weak_ref => 1);

__PACKAGE__->meta->make_immutable;

両者をとりまとめるPersonはこんな感じです。postsのなかにはテキスト記事も写真記事も入る予定です。単純にArrayRef型にしておいてもよいのですが，ここではKiokuDBで扱いやすくするためにKiokuDB::Setに対応しているオブジェクトのみ受け付けることにします。

package Person;

use Moose;
use KiokuDB::Util 'set';

has 'name'  => (is => 'rw', isa => 'Str');
has 'posts' => (
  is      => 'rw',
  does    => 'KiokuDB::Set',
  default => sub { set() },
);

__PACKAGE__->meta->make_immutable;

では，実際にオブジェクトの保存と取得をしてみましょう。KiokuDBではいくつかのバックエンドを利用できるようになっていますが，ここでは永続化の手段としてSQLiteを利用します。

use strict;
use warnings;
use KiokuDB;
use KiokuDB::Util 'set';
use Person;
use Post;
use Photo;

my $db = KiokuDB->connect( 'dbi:SQLite:db', create => 1 );

まずは必要なモジュールを読み込んで，保存用のデータベースを作成します。KiokuDBを使う際にはあらかじめスキーマなどを設定する必要はありません。KiokuDBのほうでよきにはからってくれます。

my $person_id;
{
  my $scope = $db->new_scope;

  my $person = Person->new(name => 'Foo Bar');
  my $post = Post->new(
    name   => 'my post',
    body   => 'MyPost',
    author => $person,
  );
  my $photo = Photo->new(
    name   => 'my photo',
    image  => 'MyPhoto',
    author => $person,
  );

  $person->posts(set($post, $photo));

  $person_id = $db->store($person);
}

保存するオブジェクトをつくって，データベースに入れます。保存した$personオブジェクトのUUIDが返ってくるので，あとで参照できるようにスコープ外の変数に保存しておいてください。このIDは，はじめて登録するオブジェクトであれば，自分で指定することもできます。

  $person_id = $db->store(my_id => $person);

ただし，既存のIDを持つオブジェクトの場合はstore時にIDを指定するとエラーになるので，実際にはID判定も組み込んでおいたほうが無難です。

  if ($db->object_to_id($person)) {
    $person_id = $db->store($person);
  }
  else {
    $person_id = $db->store(my_id => $person);
  }

いまつくった$person以下のオブジェクトはスコープを抜けたところでメモリから消えます。ここではまだnew_scopeの意味がわからないかもしれませんが，これはひとまずKiokuDBとデータをやりとりする際にはかならず必要なものであると思っておいてください（このスコープはウイークリファレンスの保護などの意味があります）。

{
  my $other_scope = $db->new_scope;

  my $person = $db->lookup($person_id);

  foreach my $post ($person->posts->members) {
    print $post->name, " by ", $post->author->name, "\n";
  }
}

別のスコープで，今度は先ほど保存したはずのオブジェクトを取り出してみましょう。Personオブジェクトだけでなく，Personオブジェクトのなかに保存されていたPostやPhotoのオブジェクトや，そこからのウイークリファレンスも正しく復元されていることが確認できます（もちろん実際の掲示板をつくるときにはここでpostsのメンバーをそれぞれ適切なテンプレートに埋め込む作業が発生することでしょう）。

KiokuDBはアプリケーションの仕様が変わっても柔軟に対応できます。今度はムービー記事も投稿できるようにしたいという要望があがってきました。RDBMSならテーブルの変更やらなにやらが必要になるところですが，KiokuDBの場合は表現するクラスを追加するだけで済みます。

package Movie;

use Moose;

has 'name'   => (is => 'rw', isa => 'Str');
has 'movie'  => (is => 'rw');
has 'author' => (is => 'rw', isa => 'Person', weak_ref => 1);

__PACKAGE__->meta->make_immutable;

Movieを追加するコードはこうなります。

{
  use Movie;

  my $yet_another_scope = $db->new_scope;

  my $person = $db->lookup($person_id);

  my $movie = Movie->new(
    name   => 'my movie',
    movie  => 'MyMovie',
    author => $person,
  );

  $person->posts->insert($movie);

  $db->store($person);
}

なお，このような更新部分はまるごとトランザクションでくくってしまうこともできます。この場合はなくても動作しますが，あったほうが安全ですし，一般的には速くなることが多いようです。

$db->txn_do(sub { ... });

Perl, モダンPerl, KiokuDB

石垣憲一（いしがきけんいち）

あるときは翻訳家。あるときはPerlプログラマ。先日『カクテルホントのうんちく話』（柴田書店）を上梓。最新刊は『ガリア戦記』（平凡社ライブラリー）。

URL：http://d.hatena.ne.jp/charsbar/

モダンPerlの世界へようこそ

バックナンバー一覧

このエントリのトラックバック URI

お名前
メールアドレス
タイトル
コメント

多数の情報処理技術者試験対策書籍の発行実績を誇る技術評論社がお届けする，資格試験合格サイト「めざせ！情報処理試験パスサポ」が開設されました。

サクセスストーリーに続く，快適サーバー運用管理のヒント！: データの増大，煩雑な管理，システムダウン，セキュリティなど，迫りくる課題からシステム管理者の負担を軽くするポイントを解説します。
gihyo.jp インフラエンジニア情報局: ネットワークやITにかかわるあらゆる業種で必要とされるインフラエンジニアに向けた技術情報や心構え，その魅力について多角的に紹介。
テストエンジニアステーション: いま，ITに関わるあらゆる開発業務で注目されつつあるテスト系エンジニアをターゲットにしたコンテンツサイトを展開します。

※検索はページ右上の検索ボックスをご利用ください。

もっと便利に！jQueryでラクラクサイト制作（実践サンプル付き）: 本連載では，実践サンプルとともに，jQueryを上手に活用してサイト制作の品質向上・効率化を実現するための実践テクニックを解説します。
サクセスストーリーに続く，快適サーバー運用管理のヒント！: サーバーを自社で運用管理するのはもう限界…。データの増大，煩雑な管理，システムダウン，セキュリティなど，迫りくる課題からシステム管理者の負担を軽くするポイントを解説します。
続・先取り！ Google Chrome Extensions: 2010年1月のリリースが予定されているGoogle Chrome 4に搭載されるExtensionsについて，その詳細を先取りで解説します。最新情報から，ユーザースクリプトやテーマの作り方など関連情報もお届けします。
モダンPerlの世界へようこそ: この連載では，Perlの世代間ギャップに悩んでいる方に，いくらかの背景知識と，これだけは知っておいたほうがよいという最低限の慣用句をお届けします。
Hosting Department：ホスティングを活用するための基礎知識: 本連載では，ホスティングサービスを活用する上で知っておきたい基礎知識を解説します。
Blogopolisから学ぶ計算幾何: 計算幾何学は，図形に関するアルゴリズムを研究するコンピュータサイエンスの一分野です。本連載では，ビジュアルブログ検索エンジン「Blogopolis」で採用されている計算幾何のアプローチを例に取り上げながら，計算幾何の初歩を実践的に学習します。
Windows phoneアプリケーション開発入門: Windows Marcketplace for Mobileがサービス開始され，作成したアプリケーションを個人でも世界をターゲットに公開できる環境が整ってきました。これを機にWindows phoneアプリケーションの開発をしてみませんか？
いま，見ておきたいウェブサイト: この連載では，国内外の最新のウェブサイトを隔週更新で取り上げ，これら最新サイトの特徴や素晴らしい部分を，さまざまな角度から解説していきます。