第19回　Objectクラスと静的メソッドの定義

前回の第18回「カスタムクラスを定義する」では、クラスMyTimerを定義した。今回は、このMyTimerクラスに、さらに機能を加えてみよう（前回のサンプルファイルは3ページからダウンロードできる⁠）⁠。

Objectクラスを使う

MyTimerクラスには、インスタンスを作成した時刻が保持される。この時刻は、クラスのprivateなプロパティにDateインスタンスとして設定した。

var myObject:MyTimer = new MyTimer();

そして、MyTimerクラスのgetElapsedTime()メソッドを使うと、インスタンスを作成してからの経過時間がミリ秒で取得できた[1]⁠。

var nElapsedTime:Number = myObject.getElapsedTime();

しかし、桁数の大きいミリ秒の整数より、時分秒ミリ秒の数値を個別に調べられた方が時間はわかりやすい。たとえば、Dateインスタンスであれば、それらの値はプロパティとして取出すことができた。そこで、 getElapsedTime()の戻り値をオブジェクトとして、そのプロパティから時分秒ミリ秒の数値が取出せるようにしよう。

実際、getElapsedTime()がDateインスタンスを返せば、時分秒のプロパティは得られる。しかし、それら以外の日付のプロパティやDateクラスのメソッドを使うつもりはない。したがって、もっとシンプルで軽いObjectクラスのインスタンスを用いることにする。

具体的には、getElapsedTime()メソッドの戻り値に対して、つぎのようなアクセスができるようにしたい（図1⁠）⁠。

var oElapsedTime:Object = myObject.getElapsedTime();
trace(oElapsedTime.hours);   // 時
trace(oElapsedTime.minutes);   // 分
trace(oElapsedTime.seconds);   // 秒
trace(oElapsedTime.milliseconds);   // ミリ秒

Objectクラスは、その使い方によって、いくつかの側面をもつ。今回は、配列（Arrayクラス）と似た、複数の値を収める容れ物として用いる。まず、Objectインスタンスの生成は、ActionScriptの原則どおり、コンストラクタメソッドを呼出して行う。

var myObject:Object = new Object();

つぎに、Objectインスタンスへの値の納め方だ。配列は整数インデックスに値を格納した。Objectインスタンスには、インデックスでなく変数のように識別子をつけて値を代入する。識別子は、Objectインスタンスにドットシンタックスで以下のように設定すればよい。そして、値は代入演算子=で代入する。

myObject.hours = 12;
myObject.minutes = 34;
myObject.seconds = 56;
myObject.milliseconds = 789;

さらに、値の取得も、つぎのようにドットシンタックスで行う。なお、Arrayインスタンス（配列）にインデックスをつけて納めた値は「エレメント」と呼ぶのに対して、Objectインスタンスに識別子で設定した値を「プロパティ」という。

trace(myObject.hours);   // 出力: 12
trace(myObject.minutes);   // 出力: 34
trace(myObject.seconds);   // 出力: 56
trace(myObject.milliseconds);   // 出力: 789

ミリ秒から時分秒を計算する

MyTimerクラスのメソッドgetElapsedTime()がObjectインスタンスを返すよう修正する前に、ミリ秒から時分秒を計算する方法について確認しておこう。総ミリ秒の数値をもとに、つぎのように1000（ミリ秒⁠）⁠、60（秒⁠）⁠、60（分）で順に割り、順に余りを取出せばよい。

たとえば、ミリ秒の数値から時分秒ミリ秒のプロパティ値が納められたObjectインスタンスを返す関数translateToTimeObject()は、フレームアクションとしては以下のスクリプト1のように定義できる[2]⁠。同じタイムラインからは、この関数をつぎのように試せばよい（図2⁠）⁠。

var myObject:Object = translateToTimeObject(45296789);
trace(myObject.hours);   // 出力: 12
trace(myObject.minutes);   // 出力: 34
trace(myObject.seconds);   // 出力: 56
trace(myObject.milliseconds);   // 出力: 789

スクリプト1　ミリ秒値から時分秒ミリ秒のプロパティ値が納められたObjectインスタンスを返す関数

// フレームアクション
function translateToTimeObject(nTime:Number):Object {
  var oTime:Object = new Object();
  oTime.milliseconds = nTime%1000;
  nTime = Math.floor(nTime/1000);
  oTime.seconds = nTime%60;
  nTime = Math.floor(nTime/60);
  oTime.minutes = nTime%60;
  oTime.hours = Math.floor(nTime/60);
  return oTime;
}

静的なメソッドを定義する

それでは、クラスMyTimerにtranslateToTimeObject()をメソッドとして定義しよう。問題はその定義の仕方だ。通常は、getElapsedTime()メソッドのように、インスタンスを参照して呼出すメソッドとして定義する[1]⁠。ところが、translateToTimeObject()は、インスタンスを参照する必要性がない。引数として渡された数値に算術演算を施して返すだけで、インスタンスのプロパティなどの情報がまったく要らないからだ。

このような場合、クラスの「静的（static）なメソッド」として定義することが考えられる。静的なメソッドは、Math.sin()やMath.cos()メソッドなどのように、インスタンスを作成することなくクラスを直接参照して呼出す[3]⁠。インスタンスでなく、クラス自身に定義されたメソッドである。今回、translateToTimeObject()は、クラスMyTimerの静的メソッドとして定義しよう。

静的なメソッドは、その定義に属性としてstaticを指定する（スクリプト2⁠）⁠。静的なメソッドはそれが汎用的であれば、他のクラスやフレームアクションから利用する場合も少なくない。そこで、translateToTimeObject()メソッドも、アクセス制御の属性にはpublicを指定した。以上ふたつの属性の指定を除けば、メソッドの定義は前述フレームアクションの関数（スクリプト1）と変わるところはない。

スクリプト2　MyTimerクラスに静的メソッドtranslateToTimeObject()を定義

// ActionScript 3.0クラス定義ファイル: MyTimer.as
package {
  public class MyTimer {
    private var my_date:Date;
    public function MyTimer() {
      my_date = new Date();
    }
    public function getElapsedTime():Object {
      var current_date:Date = new Date();
      var nElapsedTime:Number = current_date.time-my_date.time;
      var oElapsedTime:Object = translateToTimeObject(nElapsedTime);   // クラスの参照を省略
      return oElapsedTime;
    }
    public static function translateToTimeObject(nTime:Number):Object {
      var oTime:Object = new Object();
      oTime.milliseconds = nTime%1000;
      nTime = Math.floor(nTime/1000);
      oTime.seconds = nTime%60;
      nTime = Math.floor(nTime/60);
      oTime.minutes = nTime%60;
      oTime.hours = Math.floor(nTime/60);
      return oTime;
    }
  }
}

静的メソッドは、クラスを参照して呼出す。ただし、クラス自身の内部からアクセスする場合には、前記スクリプト2のようにクラスの参照は省略できる。translateToTimeObject()メソッドにはpublic属性を指定したので、Flashムービー（FLA）ファイルから呼出せる。たとえば、つぎのようなフレームアクションでテストしてみるとよいだろう。

var myObject:Object = MyTimer.translateToTimeObject(45296789);
trace(myObject.hours);   // 出力: 12
trace(myObject.minutes);   // 出力: 34
trace(myObject.seconds);   // 出力: 56
trace(myObject.milliseconds);   // 出力: 789

以下のようなフレームアクションを記述すれば、ステージをクリックするたびに、MyTimerインスタンスを生成してから経過した時分秒ミリ秒が[出力]パネルに表示される

var myObject:MyTimer = new MyTimer();
stage.addEventListener(MouseEvent.CLICK, xTrace);
function xTrace(eventObject:MouseEvent):void {
  var oElapsedTime:Object = myObject.getElapsedTime();
  trace(oElapsedTime.hours);
  trace(oElapsedTime.minutes);
  trace(oElapsedTime.seconds);
  trace(oElapsedTime.milliseconds);
}

今回解説した次のサンプルファイルがダウンロードできます。

スクリプト2のサンプルファイル